WebenemasunoLinkedData.es consulta SPARQL

Esta sección está desarrollada para ayudar al usuario a consultar el Web N+1.es SPARQL protocol endpoint.

Ejemplos de consultas SPARQL

Entidades involucradas en el proceso de creación de la guía:"Picoteo Dublinés" y sus roles.

SELECT distinct ?reference ?role WHERE {
   ?post <http://rdfs.org/sioc/ns#title> "Picoteo dublinés".
   ?gen <http://openprovenance.org/model/opmo#effect> ?post.
   ?gen <http://openprovenance.org/model/opmo#cause> ?process.
   ?used <http://openprovenance.org/model/opmo#effect> ?process.
   ?used <http://openprovenance.org/model/opmo#cause> ?reference.
   ?used <http://openprovenance.org/model/opmo#role> ?role.
}

Enlaces de guías (limitado a 100 guías).

SELECT DISTINCT ?a ?c WHERE {
?a a <http://webenemasuno.linkeddata.es/ontology/OPMO/Guide>.
?a <http://openprovenance.org/model/opmo#pname> ?c
} LIMIT 100

Enlace a una guía en concreto (dada la guía http://webenemasuno.linkeddata.es/elviajero/resource/Guide/20080112ELPVIAPOR_1.TES)

SELECT DISTINCT ?c WHERE {
 <http://webenemasuno.linkeddata.es/elviajero/resource/Guide/20080112ELPVIAPOR_1.TES> <http://openprovenance.org/model/opmo#pname> ?c
}

URLs de las fotos (con título y URI) asociadas a una guía (http://webenemasuno.linkeddata.es/elviajero/resource/Guide/20070519ELPVIAVJE_1.TES)

SELECT DISTINCT ?reference ?pname ?tit WHERE {
 ?gen <http://openprovenance.org/model/opmo#effect> <http://webenemasuno.linkeddata.es/elviajero/resource/Guide/20070519ELPVIAVJE_1.TES>.
 ?gen <http://openprovenance.org/model/opmo#cause> ?process.
 ?used <http://openprovenance.org/model/opmo#effect> ?process.
 ?used <http://openprovenance.org/model/opmo#cause> ?reference.
 ?reference a <http://webenemasuno.linkeddata.es/ontology/OPMO/Image>.
 ?reference <http://openprovenance.org/model/opmo#pname> ?pname.
 OPTIONAL {?reference <http://metadata.net/mpeg7/mpeg7.owl#title> ?t.
 ?t <http://www.w3.org/2000/01/rdf-schema#label> ?tit.}
}

Guías que no están bien anotadas en Barcelona (sin autor o título):

	select distinct ?guide 
	where{ 
	 ?guide a <http://webenemasuno.linkeddata.es/ontology/OPMO/Guide>.
	 ?guide <http://webenemasuno.linkeddata.es/ontology/OPMO/refersTo> <http://geo.linkeddata.es/resource/Provincia/Barcelona>.
	FILTER NOT EXISTS
	 {
	  ?guide a <http://webenemasuno.linkeddata.es/ontology/OPMO/Guide>.
	  ?guide <http://webenemasuno.linkeddata.es/ontology/OPMO/refersTo> <http://geo.linkeddata.es/resource/Provincia/Barcelona>.
	  ?guide <http://rdfs.org/sioc/ns#has_creator> ?author.
	  ?guide <http://rdfs.org/sioc/ns#title> ?title.
	 }
	}

Para más información sobre SPARQL Query Language for RDF